Will Henderson

T-mobile, in their infinite wisdom of poor customer service, does not allow you to redirect standard SMS messages, nor indeed to block or filter them in anyway, claiming that they need the service to deliver status updates, for emergencies, etc. Meanwhile, I’ve never gotten anything but SPAM and stuff from text-happy friends, all of which I don’t want at 15 cents a pop.
So while I (anxiously) await the demise of SMS and its replacement with mobile email used by all, I’ve come up with an interim solution. Why pay $10 a month for unlimited texts when I already have the (much more useful) functionality of unlimited email support on my Pearl? So then, how to pipe email to SMS? Startup teleflip has a solution: you can send an email to [phone num]@teleflip.com and it will send an sms to their phone! If they reply, it comes back to your email! Now all that remains is populating your address book with entries for people’s SMS ‘email addresses’. Applescript to the rescue! The following script goes through your address book, and for anyone with a ‘Mobile phone number set, it make it into a new email address with the label ‘SMS’. It’s smart enough to not recreate the email address if you run it multiple times. Note that you might want to create a smart group of people without mobile phone numbers so that you can make sure you don’t have some people whose mobile numbers are mislabeled as something else.

tell application "Address Book"
	repeat with this_person in every person
			set the_number to ""
			repeat with i from 1 to the count of phone in this_person
				if label of phone [i] of this_person as string is "Mobile" then
					set the_number to value of phone [i] of this_person as string
				end if
			end repeat
			if the_number is not "" then
				set isAlreadySet to "0"
				repeat with i from 1 to the count of email in this_person
					if (value of email [i] of this_person as string) ends with "@teleflip.com" then
						set isAlreadySet to "1"
					end if
				end repeat
				if isAlreadySet is "0" then
					make new email at end of emails of this_person with properties {label:"other:", value:my stripSymbolsAddEmail(the_number)}
				end if
			end if
		end repeat
	end tell

	on stripSymbolsAddEmail(inputText)
		set theSymbols to "().- "

		set prevTids to AppleScript's text item delimiters
		repeat with i in theSymbols
			set AppleScript's text item delimiters to i
			set inputText to inputText's text items
			set AppleScript's text item delimiters to prevTids
			set inputText to inputText as text
		end repeat
		if character 1 of inputText is not "1" then
			set inputText to ("1" & inputText)
		end if
		set inputText to (inputText & "@teleflip.com")
		inputText
	end stripSymbolsAddEmail
	--> thanks to http://applescriptsourcebook.com/viewtopic.php?pid=47366 for this part!

Now just sync up with your blackberry and you can send free texts. I only have a few friends who text me a lot, so I just sent them a text telling them to use this address to text me. Presumably, this would work great on the iPhone as well. Word.

Update: Apparently Pocketmac for Blackberry isn’t smart enough to sync anything email addresses labeled other than ‘work’, ‘home’ and ‘other’. Not sure if there’s a work arround other than changing those ‘SMS’ labels to ‘other’. Of course, this means we can’t simply check the label anymore since you might already have ‘other’ email addresses set (you can have multiple entries of a given label). Thus, I’ve updated the above script to check for a value ending in @teleflip.com instead. It now uses ‘other’ instead of ’sms’ as the label. Here’s an applescript to change all the old labels from ‘SMS’ to ‘other’ incase you are in my boat and already ran the script.

tell application "Address Book"
		repeat with this_person in every person
			repeat with i from 1 to the count of email in this_person
				if label of email [i] of this_person as string is "SMS" then
					set label of email [i] of this_person to "Other"
				end if
			end repeat
		end repeat
	end tell
	

Update 2: WordPress, my new host, was converting all my quotes in the above chunk of code to curly quotes automatically. Thanks! Unfortantly, pasting the code into Script Editor was thus causing an error. I’ve updated the post with manually hard-coded quotes to avoid this (thanks to this helpful post). Let me know if anyone knows a better way to get wordpress to stop being so smart.